首页 >> 读书频道 >> 电脑 >> ASP讲座之四:ASP内置组件
 
· ASP讲座之三:Appl
· ASP讲座之二:读取通过
· ASP讲座之一:网页开发
· ASP系列讲座(二十三)
· ASP系列讲座(二十二)
· ASP系列讲座(二十一)
· ASP系列讲座(二十)维
· ASP系列讲座(十九)管
· ASP系列讲座(十八)管
· ASP系列讲座(十七)调
· ASP系列讲座(十六)访
· ASP系列讲座(十五)使
 
· 美容养颜手册
· 加油金顺剧情分集介绍完整
· 红楼梦:120回全本[清
· 素质教育在美国
· 全唐诗卷四十六
· 韩剧《布拉格恋人》剧情介
· 夜航船[作者:明·张岱]
· 局外人[作者:韩·可爱淘
· 现场流行病学
· 源氏物语[日本:紫式部]
· 武林寓言故事
· 2006高考录取规则
 
· (出租)中动商场部分及写
· (出租)中动动漫基地&#
· 喜剧学院
· 《善德女王》剧情介绍
· 魔女18号 剧情
· 丑女无敌剧情介绍
· 魔女幼熙剧情介绍
· 龙游天下剧情介绍
· 震撼世界的七日剧情介绍
· 静静的白桦林剧情介绍
· 心情日记—老公今天我想对
· 旗舰剧情介绍
欢迎来到月影社区!如果您觉得这里不错,请推荐给您的朋友们。月影社区:http://wf66.com/

ASP讲座之四:ASP内置组件


查看有无更新版本

关键字:ASP教程 2006-9-8

 

前三讲中,我们主要介绍了ASP提供的四大内置对象:
Response对象:向浏览器发送信息。
Request对象:访问从浏览器发送到服务器的信息(如获取表单数据)。
Session对象:存储、读取特定用户对话信息。
Application对象:存储、读取所有用户共享的应用程序信息。
    此外还有Server对象和ObjectContext对象我们将在以后的实例中学习(提示:其实不经意之间你已经可以利用所学知识编写网上聊天室了)。本讲的内容是使用ASP的ActiveX Server Components(组件)。
一、 Browser Capabilities Component(浏览器能力组件):
我们知道,不同的浏览器也许支持不同的功能,如有些浏览器支持框架,有些不支持。利用这个组件,可以检查浏览器的能力,使你的网页争对不同的浏览器显示不同的页面(如对不支持Frame的浏览器显示不含Frame的网页)。该组件的使用很简单,需注意的是,要正确使用该组件,必须保证Browscap.ini文件是最新的(其实每一个浏览器及其特性都列在这个文件中,自己打开看看就明白了),否则结果可能相去甚远,如Win98第二版所带的IE5.0,在下例中显示为Netscape。这个文件一般位于Web服务器的“\Winnt\System32\InetSrv”下,最新的版本可去http://www.asptracker.com/或http://www.cyscape.com/browscap下载。
例:wuf22.asp
<html>
<BODY>
‘注意:组件的使用与对象类似,但是组件在使用前必须先创建,而使用内置对象前不必创建。
<%Set BrowsCap=Server.CreateObject("MSWC.BrowserType")%>
请稍候......
<P>
<TABLE BORDER=1 CELLPADDING=10>
<TR><TD>浏览器类型</TD><TD><%=BrowsCap.Browser%></TD></TR>
<TR><TD>浏览器版本</TD><TD><%=BrowsCap.version%></TD></TR>
<TR><TD>是否支持表格</TD><TD><%=BrowsCap.tables%></TD></TR>
<TR><TD>是否支持ActiveX控件</TD><TD><%=BrowsCap.activexcontrols%></TD></TR>
<TR><TD>是否支持JavaApplets</TD><TD><%=BrowsCap.javaapplets%></TD></TR>
<TR><TD>是否支持JavaScript</TD><TD><%=BrowsCap.javascript%></TD></TR>
<TR><TD>是否支持Cookies</TD><TD><%=BrowsCap.Cookies%></TD></TR>
<TR><TD>是否支持Frames</TD><TD><%=BrowsCap.Frames%></TD></TR>
<TR><TD>操作系统</TD><TD><%=BrowsCap.Platform%></TD></TR>
<TR><TD>是否支持VBScript</TD><TD><%=BrowsCap.vbscript%></TD></TR>
</TABLE>
<%Set BrowsCap = Nothing%>
</BODY>
</HTML>
注意:在本例中我们也接触了Server对象的CreateObject方法,Server.CreateObject用于创建已经注册到服务器上的ActiveX组件(说明:还有其他方法可以创建组件)。不过别忘了用“Set 对象 = Nothing”来及时释放资源,这应该成为一个习惯。
二、 File Access组件
File Access组件由FileSystemObject对象和TextStream对象组成,使用FileSystemObject对象,可以建立、检索、删除目录及文件,而TextStream对象则提供读写文件的功能。
实例wuf23.asp。强调:只有通过实践才能加深理解,实践和比较程序运行结果是快速掌握编程技巧的最好方法。
<%@ Language=VBScript %>
<% Option Explicit
' 注意绝对路径: C:\Inetpub\home\asp\wuf23.asp  主页路径: C:\Inetpub\home
Dim Path, File, FSO, CTF, Str, StrHTML, StrNoHTML
'使用 CreateObject 方法创建 FileSystemObject 对象 FSO
Set FSO = Server.CreateObject("Scripting.FileSystemObject")
Path = Server.MapPath("test")         '返回test的物理目录(绝对路径)
'就本例而言, 下面这句与上面这句返回的Path完全一样
'Path = Server.MapPath("\asp\test\")
Response.Write Path & "<Br>"
If FSO.FolderExists(Path) = false then    '判断该文件夹是否存在
FSO.CreateFolder(Path)                '新建文件夹
End If
File = Path & "\asptest.txt"
' 写文件操作
If FSO.FileExists(File) = True Then                '判断该文件是否存在
'建立 TextStream 对象 CTF
  Set CTF = FSO.OpenTextFile(File, 8, False, 0)    '打开文件, 详见说明
Else
  Set CTF = FSO.CreateTextFile(File,False, False)  '新建文件
End If
CTF.Write "<P>第一个字符串; "              '写字符串
CTF.WriteLine "第二个字符串; "             '写字符串, 并加上一个换行符
CTF.Write "第三个字符串; "
CTF.Close                                  '注意要关闭文件
' 读文件操作
Set CTF = FSO.OpenTextFile(File, 1,,0)
Do While CTF.AtEndOfStream <> True         '判别是否文件结尾(循环语句)
  Str = CTF.ReadLine                       '(每次)读取一行
  StrNoHTML = StrNoHTML & Str & "<BR>" & VbCrLf 
  StrHTML = StrHTML & Server.HTMLEncode(Str) & "<BR>" & VbCrLf
Loop
Response.Write StrNoHTML
Response.Write StrHTML
CTF.Close
Set CTF = Nothing   '释放对象
Set FSO = Nothing
%>
CTF = FSO.OpenTextFile(File, 8, False, 0),括号内第一个参数为文件名;第二个参数为8,表示在原文件后追加内容,若为1表示只读,为2则会重写原文件;第三个参数false表示,若指定文件不存在,也不新建文件,若为True,表示指定文件不存在,则新建该文件;第四个参数0表示以ASCII文件格式打开,若为-2,则表示以原来的格式打开。
CTF = FSO.CreateTextFile(File,False, False),第二个参数false表示不覆盖已有文件,若为True,则表示覆盖(OverWrite)已有文件;第三个参数为False表示文件格式为ASCII,为True表示文件格式为Unicode。
Server对象的MapPath方法将指定的虚拟路径转换为真实的文件路径。MapPath将“/”和“\”字符视为相同。
Server对象的HTMLEncode方法允许你对特定的字符串进行HTML编码,或者说使浏览器中可以正确显示特定的字符。上例中,若未编码,则“<P>”显示不出来,而是被浏览器作为HTML标记,你可以对比一下运行结果。
实际上,File Access组件对文件、文件夹和驱动器的操作还是比较强大的,也提供了较多的方法,如果需要用到这方面的知识,别忘了使用它。
另外,到现在为止,写一个网页计数器已经是小菜一碟了吧,难怪那么多的网页提供免费计数器。怎么样?自己写一个图形计数器试试看,想怎么作弊就怎么作弊,完全自己说了算,爽呆!(小秘密:我的主页上有实例wuf24.asp)
三、 AD Rotator(广告翻转组件)
现在上网,恐怕最讨厌的是别人主页上的广告条,最喜欢的是自己主页上的广告条,广告条如同垃圾邮件一样,比比皆是,防不胜防。你也可以自己动手制造这样的垃圾,ASP的AD Rotator组件就可使每次打开或者重新加载网页时,随机的显示广告。这个例子包括三部分:
例程wuf25.asp
<%@ Language=VBScript %>
<% Option Explicit
Dim adr
'创建 AD Rotator 对象
Set adr = Server.CreateObject("MSWC.AdRotator")
adr.Border = 2              '指定图形文件的边框大小
adr.Clickable = True        '指示显示的图片是否是一个超链接
adr.TargetFrame = "_blank"  '设置超链接是否要指定Frame名称,如: _TOP _NEW _PARENT
'获取将要显示的图片及超链接设置 - 在文件 AdrSet.txt 中设置
Response.Write adr.GetAdvertisement("AdrSet.txt")
%>
    AdrSet.txt内容(后面为注释,不是这个文件的内容):
REDIRECT wuf26.asp      点击广告后,转由wuf26.asp来处理
WIDTH 468               广告图片宽度
HEIGHT 60               广告图片高度
*                       分隔符
http://www.soyou.com/prog/ad/468x60_1.gif  广告图片所在位置,也可为本地图形文件
http://www.163.com/                        指向链接,若没有超链接,写入一个“-”
网易                                       文字说明
20                                         显示该广告的相对权重,即显示频率
http://fp.cache.imgis.com/images/Ad173962St1Sz1Sq1Id2.gif
http://www.sina.com.cn/
新浪网
30
http://61.139.77.73/images/canon.gif  也可以使用本地图片,如../images/flag.gif
http://www.canon.com.cn/
佳能
50
本例中一共有三个图片(图片大小468X60)及链接,每个链接的描述占四行,实际使用时,你可如法炮制,增加更多的图片。
<%  ‘wuf26.asp
  URL = Request.QueryString("url")
Response.Redirect(URL)
%>
wuf26.asp是一个最简单的处理程序,你可根据实际需要在这里加入更多的代码。
运行一下,原来这个组件的使用也很简单,你要做的就是得到自己的AdrSet.txt文件。利用这个组件,你甚至可以设计一个现在已非常时髦的广告交换主页。
四、 Content Linking组件
显然这个组件与链接有关系,如果想马上知道这个组件的具体用途,恐怕还操之过急,不妨先引用一个经典的例子:假设在网上阅读一本书,你对以下这些链接一定不会陌生:第1章、第2章、…、上一章、下一章(或前一页、后一页)等等。我们现在要做的就是如何在这些链接之间方便快速地设置跳转。
首先建一个链接列表文本文件,如urllist.txt
wuf23.asp 第1章:文件操作(File Access组件)
wuf28.asp 第2章:Content Linking组件使用示例
wuf22.asp 第3章:浏览器能力组件
链接url地址和描述之间用 Tab 键分隔。下面wuf27.asp用来列出urllist.txt中的所有链接。
<% @LANGUAGE = VBScript %>
<% Option Explicit %>
<html><head><title>Content Linking组件使用</title></head>
<body>
<h2>目录列表: 注意核心链接是第2章, 你一定要点击它</h2>
<ul>
<%
Dim NextLink, Count
'建立 Content Linking 组件
Set NextLink = Server.CreateObject("MSWC.NextLink")
'获取文件 urllist.txt 中链接数目
Count = NextLink.GetListCount("urllist.txt")
Dim url, Dscr, I
For I = 1 To Count
url = NextLink.GetNthURL ("urllist.txt", I)           '取得超链接
Dscr = NextLink.GetNthDescription ("urllist.txt", I)  '取得文字描述
Response.Write "<li><a href = """ & url & """>" & Dscr & "</a>" & vbcrlf
Next
%> 
</ul></body></html>
然后,以wuf28.asp为例说明如何自动实现上一章和下一章跳转。
<% @LANGUAGE = VBScript %>
<% Option Explicit %>
<html><head><title>这个链接要注意</title></head>
<body>
<p>这里是第 2 章的正文............</p>
<% '每个文件都包含下面这句, 就实现了自动链接%>
<!--#include file="wuf29.asp"-->
</body></html>
这里最后一句加上去就可以实现自动跳转,核心在wuf29.asp中。
<%
Dim NextLink, rank
Set NextLink = Server.CreateObject ("MSWC.NextLink")
'当前的链接在 urllist.txt 中位于第几个
rank = NextLink.GetListIndex ("urllist.txt")
Response.Write "<hr>"
If (rank > 1) Then               'rank = 1 不存在前一页
Response.Write "|<a href=""" & NextLink.GetPreviousURL("urllist.txt") & """>上一章</a>|"
End If 
If (rank < NextLink.GetListCount("urllist.txt")) Then  'rank在最后, 则没有下一页
Response.Write "|<a href=""" & NextLink.GetNextURL("urllist.txt") & """>下一章</a>|"
End If
%>
运行这个例子后,你马上能真正理解这个组件的作用,简而言之,就是不需要在每页都写一个“上一章”、“下一章”,完全通过wuf29.asp一下搞定,是不是很方便?!不然你要是手工修改链接的话,不是太麻烦了几点吗?
现在你应该明白了,网上大量的免费计数器、免费留言板、免费聊天室、广告交换网等等……,其原理都不过如此,大可不必崇拜。

ASP讲座之四:ASP内置组件

[ 1 ]
ASP讲座之四:ASP内置组件 num

打印本页 关闭

关于我们版权声明本站导航友情连结作品演示 TOP↑